# Economia Aplicada - MCO en gretl
# Archivo WAGE1.gdt
open WAGE1.gdt

# i) estimar el modelo: errores robustos
ols lwage const educ exper expersq --robust

# Usando list
list indepvar = educ exper expersq
ols lwage const indepvar --robust

#output simple: solamente R2
ols lwage const educ exper expersq --robust --simple-print

# ii) contrastar la hipótesis nula de que 
# exper tiene efecto marginal constante:

# Podemos mirar el estadistico t, o el valor p de la salida de gretl.

# También podemos usar restrict:
restrict
b[expersq]=0
end restrict

#Usando la posición de la variable en lugar del nombre (la constante es 1):
restrict
b[4]=0
end restrict

# Notar que F =t²: 42.25 = (-6.5)²
 
# alternativamente, para contrastes de significatividad podemos usar: 
omit expersq --wald

# iii) Es exper relevante?
restrict
b[exper]=0
b[expersq]=0
end restrict

# O podemos omitir ambas variables del modelo:
omit exper expersq --wald

# iv)
#Computar efecto de exper, con exper=4

ols lwage const educ exper expersq --robust
# Para guardar un vector con los coeficientes:
b = $coeff
# computar el rendimiento aproximado para exper=4
exp5th = b[3] + 2*b[4]*4

# Cuando tenemos retornos negativos a la experiencia? 
# para exp0 el efecto marginal es 0
exp0 = -b[3]/(2*b[4])
# Cuantas personas tienen retornos negativos?
smpl exper>=exp0 --restrict
# De acuerdo a la pantalla de gretl: current sample n=121
smpl --full

# vi) R2=0.30

#vii)
# Generamos las interacciones necesarias para el nuevo modelo
genr femexper = female*exper
genr femexpersq = female*expersq 
ols lwage const educ exper expersq femexper femexpersq --robust

# Contrastamos si efecto es significativamente distinto segun sexo
# la opcion --quiet no muestra el modelo restringido
restrict --quiet
b[femexper] = 0 
b[femexpersq] = 0 
end restrict 

# También
ols lwage const educ exper expersq femexper femexpersq --robust
omit femexper femexpersq --wald

# Usando add
ols lwage const educ exper expersq --robust
add femexper femexpersq --quiet