' Engle and Granger Cointegration Test

'  X(t)   = X(t-1) + e(t)                      donde e(t) ~ WN 
'  Z1(t) =  rho1 Z(t-1) + a(t)               con |rho1=1 (no-cointe) y a(t) ~ WN
'  Z2(t) = rho2 Z(t-1) + vt                  con |rho2|<1 y v(t) ~ WN
'  Y(t)  = a1 + a2 X(t) + a3 Z2(t) + Z1(t)

'  Primera etapa:   se corre la regresion (tanto para c=0 como para c= 1 por ejemplo) y 
'                          se salvan los residuos.

'  Segunda etapa: se hace un DF sobre los residuos.

'  Quiero ver lo siguiente:
'  (1)   Los valores criticos del DF para el unit root test cuando a3=0...ver 
'         que son diferentes de los standards...
'         por el hecho de que los residuos son algo estimado y no son los errores..
'   (2)  Con a3=1 para ver si se ven afectados por la inclusion de un I(0) en 
'         la regresion de cointegracion...


create u 1000

rndseed 123456


matrix(1000,9) t = 0

for !i = 1 to 1000

    scalar rho1 = 1
    scalar rho2 = 1
    scalar a1   = 0
    scalar a2   = 0.6

     smpl @first @first
     series x = 0
     series z1=0
     series z2=0
     smpl @first+1 @last
     series x   = x(-1) + nrnd
     series z1 = rho1*z1(-1) + nrnd
     series z2 = rho2*z2(-1) + nrnd
     smpl @first @last
     


     series y = a1 + a2*x + z1                          
     
     equation s1.ls y  c x
     series e1 = resid

     equation eqe11.ls D(e1) e1(-1)
     equation eqe12.ls D(e1) c e1(-1)
     equation eqe13.ls D(e1) c e1(-1) @trend

     t(!i,1)=eqe11.@tstats(1)
     t(!i,2)=eqe12.@tstats(2)
     t(!i,3)=eqe13.@tstats(2)

     series y = a1 + a2*x + z2 + z1 

     equation s2.ls y c x
     series e2 = resid

     equation eqe21.ls D(e2) e2(-1)
     equation eqe22.ls D(e2) c e2(-1)
     equation eqe23.ls D(e2) c e2(-1) @trend

     t(!i,4)=eqe21.@tstats(1)
     t(!i,5)=eqe22.@tstats(2)
     t(!i,6)=eqe23.@tstats(2)
     
equation s3.ls y c x z2
     series e3 = resid

     equation eqe31.ls D(e3) e3(-1)
     equation eqe32.ls D(e3) c e3(-1)
     equation eqe33.ls D(e3) c e3(-1) @trend

     t(!i,7)=eqe31.@tstats(1)
     t(!i,8)=eqe32.@tstats(2)
     t(!i,9)=eqe33.@tstats(2)

next

mtos(t,tstat)
genr order = @trend


' critical values

  sort ser01
  stom(ser01,t1)
  sort ser02
  stom(ser02,t2)
  sort ser03
  stom(ser03,t3)
  sort ser04
  stom(ser04,t4)
  sort ser05
  stom(ser05,t5)
  sort ser06
  stom(ser06,t6)
sort ser07
  stom(ser07,t7)
  sort ser08
  stom(ser08,t8)
  sort ser09
  stom(ser09,t9)
  sort order

  matrix(3,11) cv = 0

' Las 3 primeras columnas corresponden a los residuos de la ecuación estimada sin la variable I(0) (a3=0)
' y las 3 últimas a los residuos de la ecuación estimada con la variable I(0) (a3=1)

'  fila 1: valores críticos al 1%
  cv(1,1) = t1(10)    ' CV none
  cv(1,2) = t2(10)    ' CV intercept
  cv(1,3) = t3(10)    ' CV intercept and trend

  cv(1,5) = t4(10)    
  cv(1,6) = t5(10)
  cv(1,7) = t6(10)  

  cv(1,9) =  t7(10)    
  cv(1,10) = t8(10)
  cv(1,11) = t9(10)   


'  fila 2: valores críticos al 5%
  cv(2,1) = t1(50)   
  cv(2,2) = t2(50)
  cv(2,3) = t3(50)

  cv(2,5) = t4(50)
  cv(2,6) = t5(50)
  cv(2,7) = t6(50)  

  cv(2,9) =  t7(50)    
  cv(2,10) = t8(50)
  cv(2,11) = t9(50)   


'  fila 3: valores críticos al 10%
  cv(3,1) = t1(100)
  cv(3,2) = t2(100)
  cv(3,3) = t3(100)

  cv(3,5) = t4(100)
  cv(3,6) = t5(100)
  cv(3,7) = t6(100)

  cv(3,9) =  t7(100)    
  cv(3,10) = t8(100)
  cv(3,11) = t9(100)