' ===============================================================
'                               DISTRIBUCIÓN DICKEY-FULLER
'
'     1.-  Genera un proceso AR(1)  yt = mu +  yt-1 + et
'     2.-  Estima por OLS: 
'                   1) yt - yt-1  = b yt-1 + et
'                   2) yt - yt-1  = a + b yt-1 + et
'                   3) yt - yt-1  = a  +b yt-1 + c t + et 
'     3.-  Calcula el estadístico t del coeficiente estimado b y lo guarda en la matriz "t"
'     4.-  Repite el proceso 1000 veces
'     5.-  Los estadísticos t están en las series ser01, ser02, ser03 (no están ordenados)
'     6.-  Los valores críticos están en la matriz cv
'           Las columnas:
'             col 1 : ecuación 1
'             col 2 : ecuación 2
'             col 3 : ecuación 3
'           Las filas: 
'            fila1 : valores criticos al 1 %
'            fila2 : valores críticos al 5 %
'            fila3 : valores críticos al 10 %
'================================================================

create u 1 1000

matrix(1000,3) t = 0

scalar mu = 0

for !i = 1 to 1000

     smpl @first @first
     series y = mu
     smpl @first+1 @last
     series y =  mu + y(-1)+ nrnd 
     
     equation eq1.ls D(y) y(-1)
     equation eq2.ls D(y) c y(-1)
     equation eq3.ls D(y) c y(-1) @trend

     t(!i,1)=eq1.@tstats(1)
     t(!i,2)=eq2.@tstats(2)
     t(!i,3)=eq3.@tstats(2)

next

smpl @first @last
mtos(t,tstat)
genr order = @trend


' critical values

sort ser01
stom(ser01,t1)
sort ser02
stom(ser02,t2)
sort ser03
stom(ser03,t3)
sort order
matrix(3,3) cv = 0
'fila 1: valores críticos al 1%
cv(1,1) = t1(10)
cv(1,2) = t2(10)
cv(1,3) = t3(10)
'fila 2: valores críticos al 5%
cv(2,1) = t1(50)
cv(2,2) = t2(50)
cv(2,3) = t3(50)
'fila 3: valores críticos al 10%
cv(3,1) = t1(100)
cv(3,2) = t2(100)
cv(3,3) = t3(100)